Makes xmonad use the EWMH hints to tell panel applications about its workspaces and the windows therein. It also allows the user to interact with xmonad by clicking on panels and window lists.

You can use this module with the following in your xmonad.hs:

import XMonad
import XMonad.Hooks.EwmhDesktops

main = xmonad $ … . ewmhFullscreen . ewmh . … $ def{…}

or, if fullscreen handling is not desired, just

main = xmonad $ … . ewmh . … $ def{…}

You may also be interested in docks and withUrgencyHook, which provide support for other parts of the EWMH specification.

It's possible to customize the behaviour of ewmh in several ways:

The list of workspaces exposed to EWMH pagers (like taffybar and polybar) and clients (such as wmctrl and xdotool) may be sorted and/or filtered via a user-defined function.

To show visible workspaces first, one may switch to a Xinerama-aware sorting function:

import XMonad.Util.WorkspaceCompare

mySort = getSortByXineramaRule
main = xmonad $ … . setEwmhWorkspaceSort mySort . ewmh . … $ def{…}

Another useful example is not exposing the hidden scratchpad workspace:

import XMonad.Util.NamedScratchpad
import XMonad.Util.WorkspaceCompare

myFilter = filterOutWs [scratchpadWorkspaceTag]
main = xmonad $ … . addEwmhWorkspaceSort (pure myFilter) . ewmh . … $ def{…}

The workspace names exposed to EWMH pagers and other clients (e.g. arbtt) may be altered using a similar interface to ppRename. To configure workspace renaming, use addEwmhWorkspaceRename.

As an example, to expose workspaces uppercased:

import Data.Char

myRename :: String -> WindowSpace -> String
myRename s _w = map toUpper s

main = xmonad $ … . addEwmhWorkspaceRename (pure myRename) . ewmh . … $ def{…}

Some modules like XMonad.Actions.WorkspaceNames provide ready-made integrations:

import XMonad.Actions.WorkspaceNames

main = xmonad $ … . workspaceNamesEwmh . ewmh . … $ def{…}

The above ensures workspace names are exposed through EWMH.

When a client sends a _NET_ACTIVE_WINDOW request to activate a window, by default that window is activated by invoking the doFocus ManageHook. The EWMH specification suggests that a window manager may instead just mark the window as urgent, and this can be achieved using the following:

import XMonad.Hooks.UrgencyHook

main = xmonad $ … . setEwmhActivateHook doAskUrgent . ewmh . … $ def{…}

One may also wish to ignore activation requests from certain applications entirely:

import XMonad.Hooks.ManageHelpers

myActivateHook :: ManageHook
myActivateHook =
  className /=? "Google-chrome" <&&> className /=? "google-chrome" --> doFocus

main = xmonad $ … . setEwmhActivateHook myActivateHook . ewmh . … $ def{…}

Arbitrarily complex hooks can be used. This last example marks Chrome windows as urgent and focuses everything else:

myActivateHook :: ManageHook
myActivateHook = composeOne
  [ className =? "Google-chrome" <||> className =? "google-chrome" -?> doAskUrgent
  , pure True -?> doFocus ]

See XMonad.ManageHook, XMonad.Hooks.ManageHelpers and XMonad.Hooks.Focus for functions that can be useful here.

When a client sends a _NET_WM_STATE request to add/remove/toggle the _NET_WM_STATE_FULLSCREEN state, ewmhFullscreen uses a pair of hooks to make the window fullscreen and revert its state. The default hooks are stateless: windows are fullscreened by turning them into fullscreen floats, and reverted by sinking them into the tiling layer. This behaviour can be configured by supplying a pair of ManageHooks to setEwmhFullscreenHooks.

See XMonad.Actions.ToggleFullFloat for a pair of hooks that store the original state of floating windows.

Setting _NET_DESKTOP_VIEWPORT is typically desired but can lead to a confusing workspace list in polybar, where this information is used to re-group the workspaces by monitor. See polybar#2603.

To avoid this, you can use:

main = xmonad $ … . disableEwmhManageDesktopViewport . ewmh . … $ def{…}

Note that if you apply this configuration in an already running environment, the property may remain at its previous value. It can be removed by running:

xprop -root -remove _NET_DESKTOP_VIEWPORT

Which should immediately fix your bar.